Flash Tech Labo.

ファンクションの引数が、Array型の場合の引き渡しかた

ちょっとしたTIPSです。

引数がArray型のファンクションにパラメータを渡すには、
ダミーの配列を作って、それに格納してから引き渡してる方も
多いかと思いますが、以下の方法が楽で見た目にも分かりやすいです。

例）
var foo:Array = new Array();
foo.push("abc");
foo.push("xyz");
hoge(foo);

↓↓↓

hoge(["abc","xyz"]);

後からfooを使うのなら別ですが、
ただパラメータを渡したいだけならこれで十分です。
「こんなの常識だよ！」と思われるかもしれませんが、
意外に盲点かと思われます。
なぜなら、私が上記の書き方をしていたからです（笑）
いや～、全然気づかなかったですよ。間抜けですね。

久しぶりの記事が他愛もない話ですいません……。

htmlファイルのembedタグから、swfファイルにパラメータを渡す[AS3.0]

※[AS2.0]の場合は、こちらを参照してください

htmlファイルのembedタグからswfファイルにパラメータを渡すには、
AS2.0同様FlashVarsが使える。ただし、Flash側の処理が異なる。

・<param>タグを１行追加。
・<embed>タグに項目を追加。

[例]　変数名「option」にパラメータを渡す
<param name="FlashVars" value="option=value" />

<embed FlashVars="option=value" ... />

↑ここまでは、AS2.0の時と同じになる。

■Flash側の処理
var paramObj:Object = LoaderInfo(this.root.loaderInfo).parameters;
trace( paramObj["option"] );
のように取り出す。

また、AS2.0同様「&」で区切ることで、複数指定することができる。
[例]
<embed FlashVars="option=1&version=2" />

htmlファイルのembedタグから、swfファイルにパラメータを渡す[AS2.0]

※[AS3.0]の場合は、こちらを参照してください

htmlファイルのembedタグからswfファイルにパラメータを渡すには、FlashVarsを使う。

・<param>タグを１行追加。
・<embed>タグに項目を追加。

[例]　変数名「option」にパラメータを渡す
<param name="FlashVars" value="option=value" />

<embed FlashVars="option=value" ... />

■Flash側の処理
trace( _root.option );
のように取り出す。

また、「&」で区切ることで、複数指定することができる。
[例]
<embed FlashVars="option=1&version=2" />

addEventListenerでの無名関数内でremoveEventListenerをする方法[AS3.0]

通常「addEventListener」を使うときは
addEventListener(イベントタイプ, 関数名);
と記述し、イベントが発生したら「関数名」で指定した関数が呼び出される。

そして処理が終わったら「removeEventListener」で削除する。
removeEventListener(イベントタイプ, 関数名);

これが基本パターンだが「関数名」の箇所に直接処理を書いてしまうこともできる。
↓こんな感じ
addEventListener(イベントタイプ, function(e:Event):void{ trace("hoge"); });

しかしこうすると、この関数は名前を持たないので「removeEventListener」する時に困ってしまう。
これを解決するには「arguments.callee」を使う。
↓こんな感じ
removeEventListener(イベントタイプ, arguments.callee);

※「arguments.callee」のヘルプを見ると「現在実行中の関数への参照です」と記述されている

[プログラム例]：traceを10回実行して、終了する
public function Main()
{
    var cnt:int = 0;
    addEventListener(Event.ENTER_FRAME,
        function(e:Event):void
        {
            trace("count:"+cnt);
            cnt++;
            if(cnt==10)
            {
                removeEventListener(Event.ENTER_FRAME, arguments.callee);
            }
        }
    );
}

本当はちゃんと関数を作った方がいいんだろうけど「フラグをセットするだけ」とか、単純な使い方ならプログラムがスッキリする気がしないでもない。。。
でも、あまり使わないかな？

自分自身がstageにaddChildされたことを検知する方法[AS3.0]

親クラス内で外部クラスをaddChildした後でなければ、外部クラス内でstageを参照することはできない。
↓で、自分自身がaddChildされたことを検知できる。

public class Test extends Sprite
{
    public function Test()
    {
        trace(stage);    // null と表示される
        addEventListener(Event.ADDED_TO_STAGE, onAdded);    // class TestがaddChildされたらonAddedへ
    }

    private function onAdded(e:Event)
    {
        // この段階でstageが使用可能になる
        trace(stage);    // [object Stage] と表示される
    }
}

読み込んだ外部swf内の変数にアクセスする方法[AS3.0]

例）
読み込まれるファイル：test.swf
変数hogeがある　　　　var hoge:int;

var url:URLRequest = new URLRequest("test.swf");
var loader:Loader = new Loader();

loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadEnd);
loader.load(url);

function loadEnd(e:Event)
{
    addChild(loader);

    // 変数にアクセスする
    var obj:Object = loader.content;
    obj.hoge = 123;
    trace( obj.hoge );

    // タイムライン制御する
    var myMc:MovieClip ;
    myMc = loader.content as MovieClip;
    myMc.stop();
}

外部クラス内で、親クラス内の変数を使う[AS3.0]

親クラスの変数にアクセスするような作りは好ましくないが、いざというときのために。。。

○親クラス
package
{
    import flash.display.*;
    public class Main extends Sprite
    {
        public var hoge:String = "";    // publicをつけて外部から見えるようにする

        public function Main()
        {
            var myClass:NewClass = new NewClass();

            // addChildすることで外部クラスでparentが使えるようになる
            this.addChild(myClass);
            myClass.test();
            trace(hoge);    // hogehoge と表示される
        }
    }
}

○外部クラス
package
{
    import flash.display.*;
    public class NewClass extends Sprite
    {
        public function test()
        {
            Main(parent).hoge = "hogehoge";    // parentを親クラス名でキャストする
        }
    }
}

ちなみにアクセスしたい変数のアクセス修飾子を省略すると internal 扱いとなるので、同一パッケージ内からならアクセスが出来る。
public var hoge:String = "";
↓
var hoge:String = "";

Hello, world!

このブログでは、主に「Flash」(ActionScript)についての話題を取り扱います。

基本的には自分用の備忘録なので、説明もなくプログラムだけが貼り付けてあることもあるかと思いますが、その辺りはご了承ください。

まぁ、タイトルくらいはつけますが。。。(^_^;

「自分用の備忘録」というコンセプトなので非公開で作ろうかとも思ったのですが、私自身ネット上のテクニカル系ブログにお世話になることも多いので、こんなブログでも誰かの参考になるかもしれないと思い、公開することにしました。